-spec casefold(String :: unicode:chardata()) -> unicode:chardata().

將 String 轉換為不區分大小寫的可比較字串。當要比較兩個字串是否相等時，casefold/1 函數優先於 lowercase/1。另請參閱 equal/4。

範例

1> string:casefold("Ω and ẞ SHARP S").
"ω and ss sharp s"

-spec chomp(String :: unicode:chardata()) -> unicode:chardata().

返回一個字串，其中已從 String 中刪除任何尾隨的 \n 或 \r\n。

範例

182> string:chomp(<<"\nHello\n\n">>).
<<"\nHello">>
183> string:chomp("\nHello\r\r\n").
"\nHello\r"

-spec equal(A, B) -> boolean() when A :: unicode:chardata(), B :: unicode:chardata().

等效於 equal(A, B, true)。

-spec equal(A, B, IgnoreCase) -> boolean()
               when A :: unicode:chardata(), B :: unicode:chardata(), IgnoreCase :: boolean().

等效於 equal(A, B, IgnoreCase, none)。

-spec equal(A, B, IgnoreCase, Norm) -> boolean()
               when
                   A :: unicode:chardata(),
                   B :: unicode:chardata(),
                   IgnoreCase :: boolean(),
                   Norm :: none | nfc | nfd | nfkc | nfkd.

如果 A 和 B 相等，則返回 true，否則返回 false。

如果 IgnoreCase 為 true，則函式會在相等性測試之前即時執行 casefold。

如果 Norm 不是 none，則函式會在相等性測試之前即時套用正規化。有四種可用的正規化形式：nfc、nfd、nfkc 和 nfkd。

範例

1> string:equal("åäö", <<"åäö"/utf8>>).
true
2> string:equal("åäö", unicode:characters_to_nfd_binary("åäö")).
false
3> string:equal("åäö", unicode:characters_to_nfd_binary("ÅÄÖ"), true, nfc).
true

-spec find(String, SearchPattern) -> unicode:chardata() | nomatch
              when String :: unicode:chardata(), SearchPattern :: unicode:chardata().

等效於 find(String, SearchPattern, leading)。

-spec find(String, SearchPattern, Dir) -> unicode:chardata() | nomatch
              when String :: unicode:chardata(), SearchPattern :: unicode:chardata(), Dir :: direction().

刪除 String 中 SearchPattern 之前的任何內容，並返回字串的其餘部分，如果找不到 SearchPattern 則返回 nomatch。Dir 可以是 leading 或 trailing，表示要從哪個方向搜尋字元。

範例

1> string:find("ab..cd..ef", ".").
"..cd..ef"
2> string:find(<<"ab..cd..ef">>, "..", trailing).
<<"..ef">>
3> string:find(<<"ab..cd..ef">>, "x", leading).
nomatch
4> string:find("ab..cd..ef", "x", trailing).
nomatch

-spec is_empty(String :: unicode:chardata()) -> boolean().

如果 String 是空字串，則返回 true，否則返回 false。

範例

1> string:is_empty("foo").
false
2> string:is_empty(["",<<>>]).
true

-spec jaro_similarity(String1, String2) -> Similarity
                         when
                             String1 :: unicode:chardata(),
                             String2 :: unicode:chardata(),
                             Similarity :: float().

返回一個介於 +0.0 和 1.0 之間的浮點數，表示給定字串之間的 Jaro 相似度。具有較高相似度的字串將更接近 1.0，其中 +0.0 表示沒有相似度，1.0 表示完全匹配。

範例

1> string:jaro_similarity("ditto", "ditto").
1.0
2> string:jaro_similarity("foo", "bar").
+0.0
3> string:jaro_similarity("michelle", "michael").
0.8690476190476191
4> string:jaro_similarity(<<"Édouard"/utf8>>, <<"Claude">>).
0.5317460317460317

兩個字串之間的 Jaro 距離可以使用 JaroDistance = 1.0 - JaroSimilarity 計算。

-spec length(String :: unicode:chardata()) -> non_neg_integer().

返回 String 中字素叢集的數量。

範例

1> string:length("ß↑e̊").
3
2> string:length(<<195,159,226,134,145,101,204,138>>).
3

-spec lexemes(String :: unicode:chardata(), SeparatorList :: [grapheme_cluster()]) ->
                 [unicode:chardata()].

返回 String 中的詞素列表，由 SeparatorList 中的字素叢集分隔。

請注意，如本範例所示，String 中兩個或多個相鄰的分隔符號字素叢集會被視為一個。也就是說，產生的詞彙清單中沒有空字串。另請參閱 split/3，其會傳回空字串。

請注意，[$\r,$\n] 是一個字素叢集。

範例

1> string:lexemes("abc de̊fxxghix jkl\r\nfoo", "x e" ++ [[$\r,$\n]]).
["abc","de̊f","ghi","jkl","foo"]
2> string:lexemes(<<"abc de̊fxxghix jkl\r\nfoo"/utf8>>, "x e" ++ [$\r,$\n]).
[<<"abc">>,<<"de̊f"/utf8>>,<<"ghi">>,<<"jkl\r\nfoo">>]

-spec lowercase(String :: unicode:chardata()) -> unicode:chardata().

將 String 轉換為小寫。

請注意，在轉換要測試相等性的字串時，應使用函式 casefold/1。

範例

2> string:lowercase(string:uppercase("Michał")).
"michał"

-spec next_codepoint(String :: unicode:chardata()) ->
                        maybe_improper_list(char(), unicode:chardata()) | {error, unicode:chardata()}.

返回 String 中的第一個碼位以及 String 的剩餘部分。如果 String 為空，則返回一個空列表；如果下一個位元組無效，則返回一個 {error, String} 元組。

範例

1> string:next_codepoint(unicode:characters_to_binary("e̊fg")).
[101|<<"̊fg"/utf8>>]

-spec next_grapheme(String :: unicode:chardata()) ->
                       maybe_improper_list(grapheme_cluster(), unicode:chardata()) |
                       {error, unicode:chardata()}.

返回 String 中的第一個字素叢集以及 String 的剩餘部分。如果 String 為空，則返回一個空列表；如果下一個位元組無效，則返回一個 {error, String} 元組。

範例

1> string:next_grapheme(unicode:characters_to_binary("e̊fg")).
["e̊"|<<"fg">>]

-spec nth_lexeme(String, N, SeparatorList) -> unicode:chardata()
                    when
                        String :: unicode:chardata(),
                        N :: non_neg_integer(),
                        SeparatorList :: [grapheme_cluster()].

返回 String 中詞素編號 N，其中詞素由 SeparatorList 中的字素叢集分隔。

範例

1> string:nth_lexeme("abc.de̊f.ghiejkl", 3, ".e").
"ghi"

-spec pad(String, Length) -> unicode:charlist() when String :: unicode:chardata(), Length :: integer().

等效於 pad(String, Length, trailing)。

-spec pad(String, Length, Dir) -> unicode:charlist()
             when String :: unicode:chardata(), Length :: integer(), Dir :: direction() | both.

等效於 pad(String, Length, Dir, $ )。

-spec pad(String, Length, Dir, Char) -> unicode:charlist()
             when
                 String :: unicode:chardata(),
                 Length :: integer(),
                 Dir :: direction() | both,
                 Char :: grapheme_cluster().

使用字素叢集 Char 將 String 填充到 Length。Dir 可以是 leading、trailing 或 both，表示應在哪裡添加填充。

範例

1> string:pad(<<"He̊llö"/utf8>>, 8).
[<<72,101,204,138,108,108,195,182>>,32,32,32]
2> io:format("'~ts'~n",[string:pad("He̊llö", 8, leading)]).
'   He̊llö'
3> io:format("'~ts'~n",[string:pad("He̊llö", 8, both)]).
' He̊llö  '

-spec prefix(String :: unicode:chardata(), Prefix :: unicode:chardata()) -> nomatch | unicode:chardata().

如果 Prefix 是 String 的前綴，則刪除它並返回 String 的剩餘部分，否則返回 nomatch。

範例

1> string:prefix(<<"prefix of string">>, "pre").
<<"fix of string">>
2> string:prefix("pre", "prefix").
nomatch

-spec replace(String, SearchPattern, Replacement) -> [unicode:chardata()]
                 when
                     String :: unicode:chardata(),
                     SearchPattern :: unicode:chardata(),
                     Replacement :: unicode:chardata().

等效於 replace(String, SearchPattern, Replacement, leading)。

-spec replace(String, SearchPattern, Replacement, Where) -> [unicode:chardata()]
                 when
                     String :: unicode:chardata(),
                     SearchPattern :: unicode:chardata(),
                     Replacement :: unicode:chardata(),
                     Where :: direction() | all.

將 String 中的 SearchPattern 替換為 Replacement。Where 表示要替換 SearchPattern 的 leading、trailing 或 all 匹配項。

可以實作為

lists:join(Replacement, split(String, SearchPattern, Where)).

範例

1> string:replace(<<"ab..cd..ef">>, "..", "*").
[<<"ab">>,"*",<<"cd..ef">>]
2> string:replace(<<"ab..cd..ef">>, "..", "*", all).
[<<"ab">>,"*",<<"cd">>,"*",<<"ef">>]

-spec reverse(String :: unicode:chardata()) -> [grapheme_cluster()].

返回 String 中字素叢集的反向列表。

範例

1> Reverse = string:reverse(unicode:characters_to_nfd_binary("ÅÄÖ")).
[[79,776],[65,776],[65,778]]
2> io:format("~ts~n",[Reverse]).
ÖÄÅ

-spec slice(String, Start) -> Slice
               when
                   String :: unicode:chardata(), Start :: non_neg_integer(), Slice :: unicode:chardata().

等效於 slice(String, Length, infinity)。

-spec slice(String, Start, Length) -> Slice
               when
                   String :: unicode:chardata(),
                   Start :: non_neg_integer(),
                   Length :: infinity | non_neg_integer(),
                   Slice :: unicode:chardata().

返回 String 的子字串，最多 Length 個字素叢集，從位置 Start 開始。

範例

1> string:slice(<<"He̊llö Wörld"/utf8>>, 4).
<<"ö Wörld"/utf8>>
2> string:slice(["He̊llö ", <<"Wörld"/utf8>>], 4,4).
"ö Wö"
3> string:slice(["He̊llö ", <<"Wörld"/utf8>>], 4,50).
"ö Wörld"

-spec split(String, SearchPattern) -> [unicode:chardata()]
               when String :: unicode:chardata(), SearchPattern :: unicode:chardata().

等效於 split(String, SearchPattern, leading)。

-spec split(String, SearchPattern, Where) -> [unicode:chardata()]
               when
                   String :: unicode:chardata(),
                   SearchPattern :: unicode:chardata(),
                   Where :: direction() | all.

在遇到 SearchPattern 的地方分割 String，並返回剩餘部分。Where 預設為 leading，表示 SearchPattern 的 leading、trailing 或 all 匹配項將分割 String。

範例

0> string:split("ab..bc..cd", "..").
["ab","bc..cd"]
1> string:split(<<"ab..bc..cd">>, "..", trailing).
[<<"ab..bc">>,<<"cd">>]
2> string:split(<<"ab..bc....cd">>, "..", all).
[<<"ab">>,<<"bc">>,<<>>,<<"cd">>]

-spec take(String, Characters) -> {Leading, Trailing}
              when
                  String :: unicode:chardata(),
                  Characters :: [grapheme_cluster()],
                  Leading :: unicode:chardata(),
                  Trailing :: unicode:chardata().

等效於 take(String, Characters, false)。

-spec take(String, Characters, Complement) -> {Leading, Trailing}
              when
                  String :: unicode:chardata(),
                  Characters :: [grapheme_cluster()],
                  Complement :: boolean(),
                  Leading :: unicode:chardata(),
                  Trailing :: unicode:chardata().

等效於 take(String, Characters, Complement, leading)。

-spec take(String, Characters, Complement, Dir) -> {Leading, Trailing}
              when
                  String :: unicode:chardata(),
                  Characters :: [grapheme_cluster()],
                  Complement :: boolean(),
                  Dir :: direction(),
                  Leading :: unicode:chardata(),
                  Trailing :: unicode:chardata().

從 String 中獲取字元，只要字元是集合 Characters 的成員，或是集合 Characters 的補集。Dir 可以是 leading 或 trailing，表示要從哪個方向獲取字元。

範例

5> string:take("abc0z123", lists:seq($a,$z)).
{"abc","0z123"}
6> string:take(<<"abc0z123">>, lists:seq($0,$9), true, leading).
{<<"abc">>,<<"0z123">>}
7> string:take("abc0z123", lists:seq($0,$9), false, trailing).
{"abc0z","123"}
8> string:take(<<"abc0z123">>, lists:seq($a,$z), true, trailing).
{<<"abc0z">>,<<"123">>}

-spec titlecase(String :: unicode:chardata()) -> unicode:chardata().

將 String 轉換為首字母大寫。

範例

1> string:titlecase("ß is a SHARP s").
"Ss is a SHARP s"

-spec to_float(String) -> {Float, Rest} | {error, Reason}
                  when
                      String :: unicode:chardata(),
                      Float :: float(),
                      Rest :: unicode:chardata(),
                      Reason :: no_float | badarg.

參數 String 預期以有效的文字表示浮點數開頭（數字是 ASCII 值）。浮點數之後字串中的剩餘字元將在 Rest 中返回。

範例

1> {F1,Fs} = string:to_float("1.0-1.0e-1"),
1> {F2,[]} = string:to_float(Fs),
1> F1+F2.
0.9
2> string:to_float("3/2=1.5").
{error,no_float}
3> string:to_float("-1.5eX").
{-1.5,"eX"}

-spec to_graphemes(String :: unicode:chardata()) -> [grapheme_cluster()].

將 String 轉換為字素叢集的列表。

範例

1> string:to_graphemes("ß↑e̊").
[223,8593,[101,778]]
2> string:to_graphemes(<<"ß↑e̊"/utf8>>).
[223,8593,[101,778]]

-spec to_integer(String) -> {Int, Rest} | {error, Reason}
                    when
                        String :: unicode:chardata(),
                        Int :: integer(),
                        Rest :: unicode:chardata(),
                        Reason :: no_integer | badarg.

參數 String 預期以有效的文字表示整數開頭（數字是 ASCII 值）。整數之後字串中的剩餘字元將在 Rest 中返回。

範例

1> {I1,Is} = string:to_integer("33+22"),
1> {I2,[]} = string:to_integer(Is),
1> I1-I2.
11
2> string:to_integer("0.5").
{0,".5"}
3> string:to_integer("x=2").
{error,no_integer}

-spec trim(String) -> unicode:chardata() when String :: unicode:chardata().

等效於 trim(String, both)。

-spec trim(String, Dir) -> unicode:chardata()
              when String :: unicode:chardata(), Dir :: direction() | both.

等效於 trim(String, Dir, Whitespace})，其中 Whitespace 是不可斷開的空格碼位集，在 Unicode 標準附錄 #31 中定義為 Pattern_White_Space。

-spec trim(String, Dir, Characters) -> unicode:chardata()
              when
                  String :: unicode:chardata(),
                  Dir :: direction() | both,
                  Characters :: [grapheme_cluster()].

返回一個字串，其中已刪除前導或尾隨，或兩者的 Characters。

Dir 可以是 leading、trailing 或 both，表示要從哪個方向移除字元。

請注意，根據 Unicode 標準，[$\r,$\n] 是一個字素叢集。

範例

1> string:trim("\t  Hello  \n").
"Hello"
2> string:trim(<<"\t  Hello  \n">>, leading).
<<"Hello  \n">>
3> string:trim(<<".Hello.\n">>, trailing, "\n.").
<<".Hello">>

-spec uppercase(String :: unicode:chardata()) -> unicode:chardata().

將 String 轉換為大寫。

另請參閱 titlecase/1。

範例

1> string:uppercase("Michał").
"MICHAŁ"