-spec all(Pred, Q :: queue(Item)) -> boolean() when Pred :: fun((Item) -> boolean()).

如果 Pred(Item) 對 Q 中的所有項目 Item 都傳回 true，則傳回 true，否則傳回 false。

範例

1> Queue = queue:from_list([1,2,3,4,5]).
2> queue:all(fun (E) -> E > 3 end, Queue).
false
3> queue:all(fun (E) -> E > 0 end, Queue).
true

-spec any(Pred, Q :: queue(Item)) -> boolean() when Pred :: fun((Item) -> boolean()).

如果 Pred(Item) 對 Q 中至少一個項目 Item 傳回 true，則傳回 true，否則傳回 false。

範例

1> Queue = queue:from_list([1,2,3,4,5]).
2> queue:any(fun (E) -> E > 10 end, Queue).
false
3> queue:any(fun (E) -> E > 3 end, Queue).
true

-spec delete(Item, Q1) -> Q2 when Item :: T, Q1 :: queue(T), Q2 :: queue(T), T :: term().

傳回 Q1 的副本，其中刪除第一個與 Item 匹配的項目（如果有的話）。

範例

1> Queue = queue:from_list([1,2,3,4,5]).
2> Queue1 = queue:delete(3, Queue).
3> queue:member(3, Queue1).
false

-spec delete_r(Item, Q1) -> Q2 when Item :: T, Q1 :: queue(T), Q2 :: queue(T), T :: term().

傳回 Q1 的副本，其中刪除最後一個與 Item 匹配的項目（如果有的話）。

範例

1> Queue = queue:from_list([1,2,3,4,3,5]).
2> Queue1 = queue:delete_r(3, Queue).
3> queue:to_list(Queue1).
[1,2,3,4,5]

-spec delete_with(Pred, Q1) -> Q2
                     when
                         Pred :: fun((Item) -> boolean()),
                         Q1 :: queue(Item),
                         Q2 :: queue(Item),
                         Item :: term().

傳回 Q1 的副本，其中刪除第一個使 Pred 傳回 true 的項目（如果有的話）。

範例

1> Queue = queue:from_list([100,1,2,3,4,5]).
2> Queue1 = queue:delete_with(fun (E) -> E > 0, Queue).
3> queue:to_list(Queue1).
[1,2,3,4,5]

-spec delete_with_r(Pred, Q1) -> Q2
                       when
                           Pred :: fun((Item) -> boolean()),
                           Q1 :: queue(Item),
                           Q2 :: queue(Item),
                           Item :: term().

傳回 Q1 的副本，其中刪除最後一個使 Pred 傳回 true 的項目（如果有的話）。

範例

1> Queue = queue:from_list([1,2,3,4,5,100]).
2> Queue1 = queue:delete_with(fun (E) -> E > 10, Queue).
3> queue:to_list(Queue1).
[1,2,3,4,5]

-spec filter(Fun, Q1 :: queue(Item)) -> Q2 :: queue(Item) when Fun :: fun((Item) -> boolean() | [Item]).

傳回一個佇列 Q2，它是對 Q1 中的所有項目呼叫 Fun(Item) 的結果。

如果 Fun(Item) 返回 true，Item 會被複製到結果佇列。如果它返回 false，Item 則不會被複製。如果它返回一個列表，列表中的元素會被插入到結果佇列中，而不是 Item。

範例 1

1> Queue = queue:from_list([1,2,3,4,5]).
{[5,4,3],[1,2]}
2> Queue1 = queue:filter(fun (E) -> E > 2 end, Queue).
{[5],[3,4]}
3> queue:to_list(Queue1).
[3,4,5]

因此，Fun(Item) 返回 [Item] 在語義上等同於返回 true，就像返回 [] 在語義上等同於返回 false。但是返回列表會比返回原子產生更多的垃圾。

範例 2

1> Queue = queue:from_list([1,2,3,4,5]).
{[5,4,3],[1,2]}
2> Queue1 = queue:filter(fun (E) -> [E, E+1] end, Queue).
{[6,5,5,4,4,3],[1,2,2,3]}
3> queue:to_list(Queue1).
[1,2,2,3,3,4,4,5,5,6]

-spec filtermap(Fun, Q1) -> Q2
                   when
                       Fun :: fun((Item) -> boolean() | {true, Value}),
                       Q1 :: queue(Item),
                       Q2 :: queue(Item | Value),
                       Item :: term(),
                       Value :: term().

傳回一個佇列 Q2，它是對 Q1 中的所有項目呼叫 Fun(Item) 的結果。

如果 Fun(Item) 返回 true，Item 會被複製到結果佇列。如果它返回 false，Item 則不會被複製。如果它返回 {true, NewItem}，則此位置的佇列元素會被結果佇列中的 NewItem 取代。

範例 1

1> Queue = queue:from_list([1,2,3,4,5]).
{[5,4,3],[1,2]}
2> Queue1 = queue:filtermap(fun (E) -> E > 2 end, Queue).
{[5],[3,4]}
3> queue:to_list(Queue1).
[3,4,5]
4> Queue1 = queue:filtermap(fun (E) -> {true, E+100} end, Queue).
{"ihg","ef"}
5> queue:to_list(Queue1).
"efghi

-spec fold(Fun, Acc0, Q :: queue(Item)) -> Acc1
              when
                  Fun :: fun((Item, AccIn) -> AccOut),
                  Acc0 :: term(),
                  Acc1 :: term(),
                  AccIn :: term(),
                  AccOut :: term().

對 Queue 的連續項目 Item 呼叫 Fun(Item, AccIn)，從 AccIn == Acc0 開始。佇列會依佇列順序遍歷，即從前端到後端。Fun/2 必須傳回新的累加器，該累加器會傳遞到下一次呼叫。該函式傳回累加器的最終值。如果佇列為空，則會傳回 Acc0。

範例

1> queue:fold(fun(X, Sum) -> X + Sum end, 0, queue:from_list([1,2,3,4,5])).
15
2> queue:fold(fun(X, Prod) -> X * Prod end, 1, queue:from_list([1,2,3,4,5])).
120

-spec from_list(L :: [Item]) -> queue(Item).

傳回一個包含 L 中項目的佇列，其順序相同；列表的頭部項目成為佇列的前端項目。

-spec in(Item, Q1 :: queue(Item)) -> Q2 :: queue(Item).

將 Item 插入佇列 Q1 的後端。傳回結果佇列 Q2。

範例

1> Queue = queue:from_list([1,2,3,4,5]).
{[5,4,3],[1,2]}
2> Queue1 = queue:in(100, Queue).
{[100,5,4,3],[1,2]}
3> queue:to_list(Queue1).
[1,2,3,4,5,100]

-spec in_r(Item, Q1 :: queue(Item)) -> Q2 :: queue(Item).

將 Item 插入佇列 Q1 的前端。傳回結果佇列 Q2。

範例

1> Queue = queue:from_list([1,2,3,4,5]).
{[5,4,3],[1,2]}
2> Queue1 = queue:in_r(100, Queue).
{[5,4,3],[100,1,2]}
3> queue:to_list(Queue1).
[100,1,2,3,4,5]

-spec is_empty(Q :: queue()) -> boolean().

測試 Q 是否為空，如果是，則傳回 true，否則傳回 false。

-spec is_queue(Term :: term()) -> boolean().

測試 Term 是否為佇列，如果是，則傳回 true，否則傳回 false。請注意，即使不是由此模組建構的，此測試也會針對與佇列表示法一致的項傳回 true。另請參閱關於資料型別的註解。

-spec join(Q1 :: queue(Item), Q2 :: queue(Item)) -> Q3 :: queue(Item).

傳回一個佇列 Q3，它是將 Q1 和 Q2 連接在一起的結果，其中 Q1 在 Q2 的前面。

範例

1> Queue1 = queue:from_list([1,3]).
{[3],[1]}
2> Queue2 = queue:from_list([2,4]).
{[4],[2]}
3> queue:to_list(queue:join(Queue1, Queue2)).
[1,3,2,4]

-spec len(Q :: queue()) -> non_neg_integer().

計算並傳回佇列 Q 的長度。

-spec member(Item, Q :: queue(Item)) -> boolean().

如果 Item 與 Q 中的某些元素匹配，則傳回 true，否則傳回 false。

-spec new() -> queue(none()).

傳回一個空佇列。

-spec out(Q1 :: queue(Item)) -> {{value, Item}, Q2 :: queue(Item)} | {empty, Q1 :: queue(Item)}.

移除佇列 Q1 前端的項目。傳回元組 {{value, Item}, Q2}，其中 Item 是已移除的項目，Q2 是結果佇列。如果 Q1 為空，則傳回元組 {empty, Q1}。

範例

1> Queue = queue:from_list([1,2,3,4,5]).
{[5,4,3],[1,2]}
2> {{value, 1=Item}, Queue1} = queue:out(Queue).
{{value,1},{[5,4,3],[2]}}
3> queue:to_list(Queue1).
[2,3,4,5]

-spec out_r(Q1 :: queue(Item)) -> {{value, Item}, Q2 :: queue(Item)} | {empty, Q1 :: queue(Item)}.

移除佇列 Q1 後端的項目。傳回元組 {{value, Item}, Q2}，其中 Item 是已移除的項目，Q2 是新的佇列。如果 Q1 為空，則傳回元組 {empty, Q1}。

範例

1> Queue = queue:from_list([1,2,3,4,5]).
{[5,4,3],[1,2]}
2> {{value, 5=Item}, Queue1} = queue:out_r(Queue).
{{value,5},{[4,3],[1,2]}}
3> queue:to_list(Queue1).
[1,2,3,4]

-spec reverse(Q1 :: queue(Item)) -> Q2 :: queue(Item).

傳回一個佇列 Q2，其中包含 Q1 的項目，順序相反。

-spec split(N :: non_neg_integer(), Q1 :: queue(Item)) -> {Q2 :: queue(Item), Q3 :: queue(Item)}.

將 Q1 分成兩個。前 N 個項目會放入 Q2，其餘項目放入 Q3。

-spec to_list(Q :: queue(Item)) -> [Item].

傳回佇列中項目的列表，其順序相同；佇列的前端項目成為列表的頭部。

範例

1> Queue = queue:from_list([1,2,3,4,5]).
{[5,4,3],[1,2]}
2> List == queue:to_list(Queue).
true